Apex Intermediate Progress | ( Lessons)

Lesson: 06 | Future Methods Testing

Notes
Video

Notes

Future methods must be static methods, and can only return a void type.
The specified parameters must be primitive data types, arrays of primitive data types, or collections of primitive data types.
Future methods can’t take standard or custom objects as arguments.
Future methods are not guaranteed to execute in the same order as they are called.

public class ClassName{
  @future
  public static void MethodName(List<Id> recordIds) {
    List<Account> accounts = [Select Id, Name from Account Where Id IN :recordIds];
    //...
  }
}

The reason why objects can’t be passed as arguments to future methods is because the object can change between the time you call the method and the time that it actually executes. Remember, future methods are executed when system resources become available. In this case, the future method may have an old object value when it actually executes, which can cause all sorts of bad things to happen.

A class containing the future method:

public class Util {
    @future
    public static void insertUserWithRole(
        String uname, String al, String em, String lname) {

        Profile p = [SELECT Id FROM Profile WHERE Name='Standard User'];
        UserRole r = [SELECT Id FROM UserRole WHERE Name='COO'];
        // Create new user with a non-null user role ID 
        User u = new User(alias = al, email=em, 
            emailencodingkey='UTF-8', lastname=lname, 
            languagelocalekey='en_US', 
            localesidkey='en_US', profileid = p.Id, userroleid = r.Id,
            timezonesidkey='America/Los_Angeles', 
            username=uname);
        insert u;
    }
}

This is the class containing the main method that calls the future method defined previously.

public class MixedDMLFuture {
    public static void useFutureMethod() {
        // First DML operation
        Account a = new Account(Name='Acme');
        insert a;
        
        // This next operation (insert a user with a role) 
        // can't be mixed with the previous insert unless 
        // it is within a future method. 
        // Call future method to insert a user with a role.
        Util.insertUserWithRole(
            'mruiz@awcomputing.com', 'mruiz', 
            'mruiz@awcomputing.com', 'Ruiz');        
    }
}

Testing the future method:

@isTest
private class MixedDMLFutureTest {
    @isTest static void test1() {
        User thisUser = [SELECT Id FROM User WHERE Id = :UserInfo.getUserId()];
       // System.runAs() allows mixed DML operations in test context
        System.runAs(thisUser) {
            // startTest/stopTest block to run future method synchronously
            Test.startTest();        
            MixedDMLFuture.useFutureMethod();
            Test.stopTest();
        }
        // The future method will run after Test.stopTest();
    
        // Verify account is inserted
        Account[] accts = [SELECT Id from Account WHERE Name='Acme'];
        System.assertEquals(1, accts.size());
        // Verify user is inserted
        User[] users = [SELECT Id from User where username='mruiz@awcomputing.com'];
        System.assertEquals(1, users.size());
    }
}

Prev You need to login to have access to the quizzes. Next

Mastered by 26 users.

Apex Intermediate

A. Apex DML Operations (8 lessons)

B. Apex Classes (17 lessons)

C. Apex Triggers (9 lessons)

D. Apex Exceptions (11 lessons)

E. Asynchronous Apex (6 lessons)

F. SOSL (10 lessons)

G. Testing Apex (9 lessons)

H. Apex Fast Recap (142 lessons)

I. Build Apex Coding Skills (64 lessons)

J. Miscellaneous (17 lessons)

You need to complete all the quizzes before certification.

Go to top

Login to your account

Lesson: 06 | Future Methods Testing

Notes

Apex Intermediate